@echo off
chcp 65001 >nul
title KIROK DM - исправление запуска RAGE:MP
echo.
echo   KIROK DM - исправление ошибки MapTypesStore и вылетов при запуске
echo   ------------------------------------------------------------------
echo.
echo   Закрываю RAGE:MP и GTA 5...
for %%p in (ragemp_v.exe updater.exe ragemp_game_ui.exe GTA5.exe PlayGTAV.exe GTAVLauncher.exe) do taskkill /f /im %%p >nul 2>&1
timeout /t 2 /nobreak >nul

set "RAGE="
for /f "tokens=2,*" %%a in ('reg query "HKCU\Software\RAGE-MP" /v rage_path 2^>nul ^| find /i "rage_path"') do set "RAGE=%%b"
if not defined RAGE if exist "C:\RAGEMP\updater.exe" set "RAGE=C:\RAGEMP"
if not defined RAGE goto norage
echo   Папка RAGE:MP: %RAGE%
if not exist "%RAGE%\client_resources" goto gta
rd /s /q "%RAGE%\client_resources"
if exist "%RAGE%\client_resources" echo   [!] Не удалось удалить client_resources - запусти файл от имени администратора.
if not exist "%RAGE%\client_resources" echo   [OK] Удалён кэш серверов client_resources: карты и машины с других серверов.
goto gta

:norage
echo   [!] Папка RAGE:MP не найдена. Установи клиент с rage.mp и запусти этот файл снова.

:gta
set "GTA="
for /f "tokens=2,*" %%a in ('reg query "HKCU\Software\RAGE-MP" /v game_v_path 2^>nul ^| find /i "game_v_path"') do set "GTA=%%b"
if not defined GTA goto done
echo   Папка GTA 5: %GTA%
if not exist "%GTA%\mods" goto done
if exist "%GTA%\mods_off_kirok" goto modsbusy
ren "%GTA%\mods" mods_off_kirok
if exist "%GTA%\mods_off_kirok" echo   [OK] Моды OpenIV отключены: папка mods переименована в mods_off_kirok.
if exist "%GTA%\mods" echo   [!] Не удалось переименовать папку mods - запусти файл от имени администратора.
goto done

:modsbusy
echo   [!] В папке GTA 5 есть и mods, и mods_off_kirok. Перенеси моды из mods вручную.

:done
echo.
echo   Если ошибка повторится, проверь целостность файлов GTA 5:
echo     Steam - Библиотека - GTA V - Свойства - Установленные файлы - Проверить
echo     Epic Games - Библиотека - GTA V - три точки - Управление - Проверить
echo     Rockstar Launcher - Настройки - GTA V - Проверить целостность
echo.
if not defined RAGE goto end
reg add "HKCU\Software\RAGE-MP" /v launch2.ip /t REG_SZ /d 188.130.132.59 /f >nul 2>&1
reg add "HKCU\Software\RAGE-MP" /v launch2.port /t REG_SZ /d 22005 /f >nul 2>&1
choice /c YN /n /m "  Запустить RAGE:MP и зайти на KIROK DM сейчас? [Y/N] "
if errorlevel 2 goto end
pushd "%RAGE%"
start "" "%RAGE%\updater.exe"
popd
echo   Запускаю. Если сервер не откроется сам: Direct Connect - 188.130.132.59:22005
:end
echo.
pause